Dynamically specifying which parameters to estimate in stan

[marianklose]

@edm

I think you could vectorize your parameters, with the vector length changing depending on number of cycles. In the data block, I would add

int ncycles;

Then, when you declare parameters, use lines like

vector[ncycles] KAPPA_CL;

Then, instead of the if-else statements in transformed parameters, you could choose a specific parameter via

KAPPA_CL[ CYCLE[i] ];

Thanks a lot, this solution worked for me. Exactly what I needed! Here are the updated blocks:

data {
    // cycles
    int<lower = 1> nCycles;                 // number of cycles
}

parameters {
    // clearance
    real ETA_CL;                                 // ind. iiv estimate
    vector[nCycles] KAPPA_CL;                    // ind. iov estimates (vectorized)

    // intercompartmental clearance q3
    real ETA_Q3;                                 // ind. iiv q3 estimates
    vector[nCycles] KAPPA_Q3;                    // ind. iov q3 estimates (vectorized)
}

transformed parameters {
    array[nEvents, nTheta] real theta;
    for (i in 1:nEvents) {

        // store thetas
        theta[i, 1] = TVCL * pow(EGFR[i] / 84, TH_EGFR_CL) * exp(ETA_CL + KAPPA_CL[ CYCLE[i] ]);
        theta[i, 2] = TVV1;
        theta[i, 3] = TVQ2;
        theta[i, 4] = TVV2;
        theta[i, 5] = TVQ3 * exp(ETA_Q3 + KAPPA_Q3[ CYCLE[i] ]);
        theta[i, 6] = TVV3;
    }
}

model {
    // informative priors for clearance
    ETA_CL ~ normal(0, IIV_SD_CL);              // IIV (sd) on central clearance
    KAPPA_CL ~ normal(0, IOV_SD_CL);            // IIV (sd) on central clearance (vectorized)

    // informative priors for intercompartmental clearance Q3
    ETA_Q3 ~ normal(0, IIV_SD_Q3);              // IOV (sd) on intercompartimental clearance Q3
    KAPPA_Q3 ~ normal(0, IOV_SD_Q3);            // IIV (sd) on intercompartimental clearance Q3 (vectorized)

    // likelihood function for exponential error model (expects SD for normal distribution)
    logCObs ~ normal(log_cHatObs, EXP_RUV_SD);
}

It is good to know that this vectorized approach works, makes my life much easier!

@Bob_Carpenter

@marianklose

Is there a way to dynamically specify which parameters should be estimated and which should be ignored when fewer cycles are provided?

@marianklose

Will this destabilize the model, or will the posterior for these parameters simply remain equal to the prior without additional convergence issues?

The latter—the posterior will be equal to the prior so it shouldn’t cause any convergence issues unless your priors are very wide or if you have very high dimensionality of uninformative parameters, at which point they might slow things down a little.

@marianklose

Does it make sense to assign a very tight prior to parameters that do not need to be estimated?

No. This will have problems if you make them too tight. Stan has to figure out the scale of parameters and if you make them very tight (e.g., normal(0, 1e-10), then random inits will be problematic because they’re so far into the tail.

@marianklose

Alternatively, could I even set a prior density of 0 for these parameters?

That’s even worse—this will grind HMC to a halt.

@marianklose

Is there any built-in way to disable parameters in the model when they are not needed?

Not directly—we usually just do what @edm suggested.

Thanks a lot for the additional explanations, makes all sense now!